Pravidla autorizace jsou skripty napsané v jazyce VBScript nebo v jazyce JScript, které můžete použít v definicích rolí a v definicích úloh. Ověřovací pravidlo určuje, zda je role či úloha povolena.

Pomocí ověřovacích pravidel můžete založit rozhodování o autorizaci na jakékoli podmínce, kterou lze otestovat skriptem. Mohou to být například oprávnění a povolení, určitá hodina, omezení výdajů, zůstatky účtů nebo jiná kritéria.

Nástroj Správce autorizací není určen k psaní či ladění ověřovacích pravidel. Skripty můžete psát v textovém editoru (například Poznámkový blok), integrovaném vývojovém prostředí, jako je Visual Studio .NET, či jiné aplikaci. Ověřovací pravidla obvykle píší profesionální vývojáři.

Další informace o vytváření ověřovacích pravidel a používání rozhraní API nástroje Správce autorizací naleznete v tématu Model nástroje Správce autorizací (stránka může být v angličtině). Další užitečné odkazy naleznete v kapitole Zdroje pro nástroj Správce autorizací.

Řízení použití obchodních a ověřovacích pravidel

Řízení použití v jednotlivých klientech

Od verze systému Windows Server 2008 lze použití obchodních a ověřovacích pravidel řídit pomocí nastavení registru. Pravidla jsou ve výchozím nastavení vypnuta. Předchozí verze systému Windows tuto funkci nepodporovaly.

Pokud používáte ve svém prostředí ověřovací a obchodní pravidla, budete je obvykle spouštět pomocí skriptu nebo instalačního programu spouštěného operačním systémem.

Důležité informace

Toto nastavení je specifické pro každý nástroj Správce autorizací v jednotlivých klientech.

Následující příklad zapíná a vypíná obchodní a aplikační pravidla určité aplikace:

'

' Enabling or disabling BizRules for an application

' This script uses Authorization Manager Administrative interfaces to enable or disable

' BizRules for a specified Authorization Manager application in a specified Authorization Manager policy store

On Error Resume Next

Set objArgs = WScript.Arguments

If objArgs.count <> 3 then

wscript.echo "Usage: SetBizRule ""AzManStoreURL"" ""AzApplicaitonName"" True/False"

wscript.echo "Example: SetBizRule ""msxml://d:\inetpub\wwwroot\AzStore.xml"" ""MyApp"" True"

wscript.echo "Run with 'cscript' command in cmd.exe to avoid msg boxes"

Else

' VBScript source code

Dim AzStoreObj

Dim AzManStoreURL : AzManStoreURL = objArgs(0)

Dim AzManAppName : AzManAppName = objArgs(1)

Dim BizRulesEnabled : BizRulesEnabled = objArgs(2)

' create azman object

Set AzStoreObj = CreateObject("AzRoles.AzAuthorizationStore")

If Err.Number > 0 Then

WScript.Echo "Can not create AzRoles.AzAuthorizationStore. Check Authorization Manager installation"

WScript.Quit

End If

' initialize store for Administration

' assumes store exists - if store is being created (e.g. an installing applicaion)

' use the value 3 instead of 2 in the call to IAzAuthorizationStore::initialize

Err.Clear

AzStoreObj.Initialize 2, AzManStoreURL

If Err.Number <> 0 Then

WScript.Echo "AzRoles.AzAuthorizationStore failed to initialize. Check store URL"

WScript.Quit

End If

' open applicaion

set AzApp = AzStoreObj.OpenApplication(AzManAppName)

If Err.Number <> 0 Then

WScript.Echo "AzRoles.AzAuthorizationStore failed to open application: " + AzManAppName + ". Check application Name."

WScript.Quit

End If

' set BizRulesEnabled property

WSCript.Echo "App BizRule Before:" & AzApp.BizRulesEnabled

AzApp.BizRulesEnabled = BizRulesEnabled

WSCript.Echo "App BizRule After:" & AzApp.BizRulesEnabled

If Err.Number = 0 Then

WScript.Echo "BizRulesEnabled is updated successfully."

Else

WScript.Echo "BizRulesEnabled is NOT updated successfully."

End If

End if

Řízení použití v celém úložišti autorizací

Konfigurací omezení ověřovacího pravidla na kartě Omezení listu vlastností úložiště ověření můžete:

  • Vypnout ověřovací a obchodní pravidla v daném úložišti

  • Nastavit hodnotu časového limitu, který omezí délku spuštění skriptu

  • Povolit spouštění skriptů bez jakéhokoli časového limitu

Další informace naleznete v části Vysvětlení omezení úložiště nástroje Správce autorizací.

Příklad skriptu v jazyce VBScript

Následující příklad obsahuje ověřovací pravidlo VBScript, které vždy udělí oprávnění:

AzBizRuleContext.BusinessRuleResult = True

Další informace o jazyce VBScript naleznete v tématu VBScript (stránka může být v angličtině).   

Příklad skriptu v jazyce JScript

Následující příklad obsahuje ověřovací pravidlo v jazyce JScript, které vždy udělí oprávnění:

AzBizRuleContext.BusinessRuleResult = true;

Další informace o jazyce JScript naleznete v tématu JScript (stránka může být v angličtině).   


Obsah