Autorisationsregler er regler, der er skrevet i VBScript eller JScript, og som du kan medtage i rolledefinitioner og opgavedefinitioner. En autorisationsregel fastslår, om rollen eller opgaven er tilladt.

Ved hjælp af autorisationsregler kan du træffe beslutninger om godkendelse på baggrund af de forhold, et script kan teste. Disse forhold kan omfatte rettigheder og tilladelser, tidspunkt på dagen, grænser for udgifter, der kan faktureres, kontosaldi eller andre kriterier.

Authorization Manager er ikke udviklet til at skrive eller foretage fejlfinding af autorisationsregler. Du kan skrive scripter i en teksteditor (f.eks. Notesblok), i et integreret udviklingsmiljø som Visual Studio .NET eller i et andet program efter eget valg. Autorisationsregler skrives som regel af udviklere.

Du kan finde flere oplysninger om oprettelse af autorisationsregler og brug af API'er (Application Programming Interfaces) under Authorization Manager-model. Siden er evt. på engelsk. (https://go.microsoft.com/fwlink/?linkid=64027). Du kan finde flere forslag til links under Ressourcer til Authorization Manager.

Styre anvendelsen af forretningsregler og autorisationsregler

Styre anvendelsen på de enkelte klienter

Fra og med Windows Server 2008 kan brugen af forretningsregler og autorisationsregler styres via en indstilling i registreringsdatabasen. Regler er som standard deaktiveret. I tidligere versioner af Windows var denne funktion ikke understøttet.

Du bruger som regel et installationsprogram eller et script, der køres af operativsystemet, til at aktivere autorisationsregler og forretningsregler, hvis de er i brug i miljøet.

Vigtigt!

Denne indstilling styres for de enkelte Authorization Manager-programmer på de enkelte klienter.

Nedenfor vises et eksempelscript, der aktiverer eller deaktiverer forretningsregler og programregler for et program:

'

' Enabling or disabling BizRules for an application

' This script uses Authorization Manager Administrative interfaces to enable or disable

' BizRules for a specified Authorization Manager application in a specified Authorization Manager policy store

On Error Resume Next

Set objArgs = WScript.Arguments

If objArgs.count <> 3 then

wscript.echo "Usage: SetBizRule ""AzManStoreURL"" ""AzApplicaitonName"" True/False"

wscript.echo "Example: SetBizRule ""msxml://d:\inetpub\wwwroot\AzStore.xml"" ""MyApp"" True"

wscript.echo "Run with 'cscript' command in cmd.exe to avoid msg boxes"

Else

' VBScript source code

Dim AzStoreObj

Dim AzManStoreURL : AzManStoreURL = objArgs(0)

Dim AzManAppName : AzManAppName = objArgs(1)

Dim BizRulesEnabled : BizRulesEnabled = objArgs(2)

' create azman object

Set AzStoreObj = CreateObject("AzRoles.AzAuthorizationStore")

If Err.Number > 0 Then

WScript.Echo "Can not create AzRoles.AzAuthorizationStore. Check Authorization Manager installation"

WScript.Quit

End If

' initialize store for Administration

' assumes store exists - if store is being created (e.g. an installing applicaion)

' use the value 3 instead of 2 in the call to IAzAuthorizationStore::initialize

Err.Clear

AzStoreObj.Initialize 2, AzManStoreURL

If Err.Number <> 0 Then

WScript.Echo "AzRoles.AzAuthorizationStore failed to initialize. Check store URL"

WScript.Quit

End If

' open applicaion

set AzApp = AzStoreObj.OpenApplication(AzManAppName)

If Err.Number <> 0 Then

WScript.Echo "AzRoles.AzAuthorizationStore failed to open application: " + AzManAppName + ". Check application Name."

WScript.Quit

End If

' set BizRulesEnabled property

WSCript.Echo "App BizRule Before:" & AzApp.BizRulesEnabled

AzApp.BizRulesEnabled = BizRulesEnabled

WSCript.Echo "App BizRule After:" & AzApp.BizRulesEnabled

If Err.Number = 0 Then

WScript.Echo "BizRulesEnabled is updated successfully."

Else

WScript.Echo "BizRulesEnabled is NOT updated successfully."

End If

End if

Styre anvendelsen for hele autorisationslageret

Ved at konfigurere grænserne for autorisationsregler under fanen Grænser i egenskabsarket for autorisationslageret kan du gøre følgende:

  • deaktivere autorisationsregler og forretningsregler for lageret

  • angive en timeoutværdi for at begrænse den tid, et script højst må køres

  • tillade, at scripter køres uden timeout.

Du kan finde flere oplysninger under Om Authorization Manager-lagerbegrænsninger.

Eksempel på VBScript

Nedenfor vises en VBScript-autorisationsregel, der altid tildeler en tilladelse:   

AzBizRuleContext.BusinessRuleResult = True

Du kan finde flere oplysninger om VBScript under VBScript. Siden er evt. på engelsk. (https://go.microsoft.com/fwlink/?linkid=65964).   

Eksempel på JScript

Nedenfor vises en JScript-autorisationsregel, der altid tildeler en tilladelse:   

AzBizRuleContext.BusinessRuleResult = true;

Du kan finde flere oplysninger om JScript under JScript. Siden er evt. på engelsk. (https://go.microsoft.com/fwlink/?linkid=65963).   


Indholdsfortegnelse