Οι κανόνες και οι δέσμες ενεργειών εξουσιοδότησης συντάσσονται σε VBScript ή JScript που μπορείτε να συμπεριλάβετε σε ορισμούς ρόλων και εργασιών. Ένας κανόνας εξουσιοδότησης καθορίζει αν επιτρέπεται ο ρόλος ή η εργασία.
Χρησιμοποιώντας κανόνες εξουσιοδότησης, μπορείτε να βασίσετε τις αποφάσεις εξουσιοδότησης σε οποιαδήποτε συνθήκη μπορεί να ελέγξει μια δέσμη ενεργειών. Μπορεί να περιλαμβάνουν δικαιώματα και προνόμια, την ώρα της ημέρας, όρια δαπανών για τιμολόγηση, ισολογισμούς ή άλλα κριτήρια.
Η Διαχείριση εξουσιοδοτήσεων δεν είναι σχεδιασμένη για τη σύνταξη ή τον εντοπισμό σφαλμάτων με τους κανόνες εξουσιοδότησης. Μπορείτε να συντάξετε τις δέσμες ενεργειών σε ένα πρόγραμμα επεξεργασίας κειμένου (όπως το Notepad), σε ένα ενιαίο περιβάλλον ανάπτυξης όπως το Visual Studio .NET ή σε άλλη εφαρμογή της επιλογής σας. Οι κανόνες εξουσιοδότησης συντάσσονται συνήθως από επαγγελματίες προγραμματιστές.
Για περισσότερες πληροφορίες σχετικά με τη δημιουργία κανόνων εξουσιοδότησης και τη χρήση των διασυνδέσεων προγραμματισμού εφαρμογών (API) της Διαχείρισης εξουσιοδοτήσεων, ανατρέξτε στο θέμα
Έλεγχος της χρήσης των επιχειρησιακών κανόνων και των κανόνων εξουσιοδότησης
Έλεγχος της χρήσης σε κάθε σύστημα-πελάτη
Ξεκινώντας με τα Windows Server 2008, η χρήση των επιχειρησιακών κανόνων και των κανόνων εξουσιοδότησης ελέγχεται από μια ρύθμιση του μητρώου. Οι κανόνες απενεργοποιούνται από προεπιλογή. Οι προηγούμενες εκδόσεις των Windows δεν υποστηρίζουν αυτές τις λειτουργίες.
Γενικά, μπορείτε να χρησιμοποιήσετε ένα πρόγραμμα ρύθμισης ή μια δέσμη ενεργειών που εκτελείται από το λειτουργικό σύστημα για να ενεργοποιήσετε τους κανόνες εξουσιοδότησης και τους επιχειρησιακούς κανόνες αν χρησιμοποιούνται στο περιβάλλον σας.
Σημαντικό | |
Αυτή η ρύθμιση ελέγχεται μεμονωμένα για κάθε εφαρμογή Διαχείρισης εξουσιοδοτήσεων σε κάθε σύστημα-πελάτη. |
Τα παρακάτω είναι ένα δείγμα δέσμης ενεργειών που ενεργοποιεί ή απενεργοποιεί τους επιχειρησιακούς κανόνες και τους κανόνες εξουσιοδότησης για μια εφαρμογή:
'
' Enabling or disabling BizRules
for an application
' This script uses Authorization Manager Administrative interfaces to enable or disable
' BizRules for a specified Authorization Manager application in a specified Authorization Manager policy store
On Error Resume Next
Set objArgs = WScript.Arguments
If objArgs.count <> 3 then
wscript.echo "Usage: SetBizRule ""AzManStoreURL"" ""AzApplicaitonName"" True/False"
wscript.echo "Example: SetBizRule ""msxml://d:\inetpub\wwwroot\AzStore.xml"" ""MyApp"" True"
wscript.echo "Run with 'cscript' command in cmd.exe to avoid msg boxes"
Else
' VBScript source code
Dim AzStoreObj
Dim AzManStoreURL : AzManStoreURL = objArgs(0)
Dim AzManAppName : AzManAppName = objArgs(1)
Dim BizRulesEnabled : BizRulesEnabled = objArgs(2)
' create azman object
Set AzStoreObj = CreateObject("AzRoles.AzAuthorizationStore")
If Err.Number > 0 Then
WScript.Echo "Can not create AzRoles.AzAuthorizationStore. Check Authorization Manager installation"
WScript.Quit
End If
' initialize store for Administration
' assumes store exists - if store is being created (e.g. an installing applicaion)
' use the value 3 instead of 2 in the call to IAzAuthorizationStore::initialize
Err.Clear
AzStoreObj.Initialize 2, AzManStoreURL
If Err.Number <> 0 Then
WScript.Echo "AzRoles.AzAuthorizationStore failed to initialize. Check store URL"
WScript.Quit
End If
' open applicaion
set AzApp = AzStoreObj.OpenApplication(AzManAppName)
If Err.Number <> 0 Then
WScript.Echo "AzRoles.AzAuthorizationStore failed to open application: " + AzManAppName + ". Check application Name."
WScript.Quit
End If
' set BizRulesEnabled property
WSCript.Echo "App BizRule Before:" & AzApp.BizRulesEnabled
AzApp.BizRulesEnabled = BizRulesEnabled
WSCript.Echo "App BizRule After:" & AzApp.BizRulesEnabled
If Err.Number = 0 Then
WScript.Echo "BizRulesEnabled is updated successfully."
Else
WScript.Echo "BizRulesEnabled is NOT updated successfully."
End If
End if
Έλεγχος της χρήσης για ολόκληρο το χώρο αποθήκευσης εξουσιοδοτήσεων
Ρυθμίζοντας τις παραμέτρους για τα όρια του κανόνα εξουσιοδότησης από την καρτέλα Όρια του φύλλου ιδιοτήτων για το χώρο αποθήκευσης εξουσιοδοτήσεων, μπορείτε:
-
Nα απενεργοποιείτε τους κανόνες εξουσιοδότησης και τους επιχειρησιακούς κανόνες για το χώρο αποθήκευσης.
-
Nα ορίζετε μια τιμή χρονικού ορίου για να περιορίσετε τη μέγιστη χρονική διάρκεια που επιτρέπεται για τη χρήση μιας δέσμης ενεργειών.
-
Nα επιτρέπετε την εκτέλεση δεσμών ενεργειών χωρίς χρονικό όριο.
Για περισσότερες πληροφορίες, ανατρέξτε στο θέμα Κατανόηση των ορίων για τους χώρους αποθήκευσης της Διαχείρισης εξουσιοδοτήσεων.
Παράδειγμα VBScript
Ακολουθεί ένας κανόνας εξουσιοδότησης σε VBScript που εκχωρεί πάντα εξουσιοδότηση:
AzBizRuleContext.BusinessRuleResult = True
Για περισσότερες πληροφορίες σχετικά με τη VBScript, ανατρέξτε στο θέμα
Παράδειγμα JScript
Ακολουθεί ένας κανόνας εξουσιοδότησης σε JScript που εκχωρεί πάντα εξουσιοδότηση:
AzBizRuleContext.BusinessRuleResult = true;
Για περισσότερες πληροφορίες σχετικά με τη JScript, ανατρέξτε στο θέμα