Le regole di autorizzazione sono script scritti in VBScript o JScript che è possibile includere nelle definizioni di ruolo e di attività. Una regola di autorizzazione determina se l'attività o il ruolo è consentito.

Utilizzando le regole di autorizzazione è possibile basare le decisioni relative alle autorizzazioni su qualsiasi condizione verificabile mediante uno script, ad esempio su privilegi e autorizzazioni, nonché sull'ora del giorno, sui limiti di spesa fatturabili, sui bilanci e su altri criteri.

Gestione autorizzazioni non è progettato per la scrittura o il debug di regole di autorizzazione. È possibile scrivere script in un editor di testo, ad esempio il Blocco note, in un ambiente di sviluppo integrato come Visual Studio .NET o in un'altra applicazione. Le regole di autorizzazione vengono in genere scritte dagli sviluppatori professionisti.

Per ulteriori informazioni sulla creazione di regole di autorizzazione e sull'utilizzo delle API (Application Programming Interface) di Gestione autorizzazioni, vedere la pagina relativa al modello di Gestione autorizzazioni (https://go.microsoft.com/fwlink/?linkid=64027). Per ulteriori collegamenti consigliati, vedere Risorse per Gestione autorizzazioni.

Controllare l'utilizzo di regole business e regole di autorizzazione

Controllare l'utilizzo su ogni client

A partire da Windows Server 2008, è possibile controllare l'utilizzo di regole business e regole di autorizzazione tramite un'impostazione del Registro di sistema. Le regole sono disabilitate per impostazione predefinita. Nelle versioni precedenti di Windows tale funzionalità non è supportata.

Per abilitare le regole di autorizzazione e le regole business eventualmente utilizzate nell'ambiente si utilizza in genere un programma di configurazione oppure uno script eseguito dal sistema operativo.

Importante

Tale impostazione viene controllata individualmente per ogni applicazione di Gestione autorizzazioni su ogni client.

Nell'esempio seguente viene illustrato uno script che consente di abilitare o disabilitare le regole business e le regole di autorizzazione per un'applicazione:

'

' Enabling or disabling BizRules for an application

' This script uses Authorization Manager Administrative interfaces to enable or disable

' BizRules for a specified Authorization Manager application in a specified Authorization Manager policy store

On Error Resume Next

Set objArgs = WScript.Arguments

If objArgs.count <> 3 then

wscript.echo "Usage: SetBizRule ""AzManStoreURL"" ""AzApplicaitonName"" True/False"

wscript.echo "Example: SetBizRule ""msxml://d:\inetpub\wwwroot\AzStore.xml"" ""MyApp"" True"

wscript.echo "Run with 'cscript' command in cmd.exe to avoid msg boxes"

Else

' VBScript source code

Dim AzStoreObj

Dim AzManStoreURL : AzManStoreURL = objArgs(0)

Dim AzManAppName : AzManAppName = objArgs(1)

Dim BizRulesEnabled : BizRulesEnabled = objArgs(2)

' create azman object

Set AzStoreObj = CreateObject("AzRoles.AzAuthorizationStore")

If Err.Number > 0 Then

WScript.Echo "Can not create AzRoles.AzAuthorizationStore. Check Authorization Manager installation"

WScript.Quit

End If

' initialize store for Administration

' assumes store exists - if store is being created (e.g. an installing applicaion)

' use the value 3 instead of 2 in the call to IAzAuthorizationStore::initialize

Err.Clear

AzStoreObj.Initialize 2, AzManStoreURL

If Err.Number <> 0 Then

WScript.Echo "AzRoles.AzAuthorizationStore failed to initialize. Check store URL"

WScript.Quit

End If

' open applicaion

set AzApp = AzStoreObj.OpenApplication(AzManAppName)

If Err.Number <> 0 Then

WScript.Echo "AzRoles.AzAuthorizationStore failed to open application: " + AzManAppName + ". Check application Name."

WScript.Quit

End If

' set BizRulesEnabled property

WSCript.Echo "App BizRule Before:" & AzApp.BizRulesEnabled

AzApp.BizRulesEnabled = BizRulesEnabled

WSCript.Echo "App BizRule After:" & AzApp.BizRulesEnabled

If Err.Number = 0 Then

WScript.Echo "BizRulesEnabled is updated successfully."

Else

WScript.Echo "BizRulesEnabled is NOT updated successfully."

End If

End if

Controllare l'utilizzo per l'intero archivio autorizzazioni

La configurazione di limiti per le regole di autorizzazione nella scheda Limiti della finestra delle proprietà dell'archivio autorizzazioni consente di eseguire le operazioni seguenti:

  • Disattivare le regole di autorizzazione e le regole business per l'archivio.

  • Impostare un valore di timeout per limitare la durata massima consentita per l'esecuzione di uno script.

  • Consentire l'esecuzione di script senza alcun timeout.

Per ulteriori informazioni, vedere Informazioni sui limiti degli archivi di Gestione autorizzazioni

Esempio di VBScript

Di seguito è riportata una regola di autorizzazione VBScript che concede sempre l'autorizzazione.

AzBizRuleContext.BusinessRuleResult = True

Per ulteriori informazioni su VBScript, vedere la pagina relativa a VBScript (https://go.microsoft.com/fwlink/?linkid=65964).   

Esempio di JScript

Di seguito è riportata una regola di autorizzazione JScript che concede sempre l'autorizzazione.

AzBizRuleContext.BusinessRuleResult = true;

Per ulteriori informazioni su JScript, vedere la pagina relativa a JScript (https://go.microsoft.com/fwlink/?linkid=65963).   


Argomenti della Guida