Autorisatieregels zijn in VBScript of JScript geschreven scripts die u kunt opnemen in functiedefinities en taakdefinities. Een autorisatieregel bepaalt of de functie of taak is toegestaan.
Als u autorisatieregels gebruikt, kunt u autorisatie verlenen op basis van een willekeurige voorwaarde die door een script kan worden getest. U kunt hierbij denken aan bevoegdheden en machtigingen, het tijdstip, limieten voor factureerbare kosten, rekeningsaldi of andere criteria.
Autorisatiebeheer is niet ontworpen voor het schrijven van autorisatieregels of het opsporen van fouten in dergelijke regels. Schrijf uw scripts bij voorkeur in een teksteditor (bijvoorbeeld Kladblok), in een geïntegreerde ontwikkelingsomgeving zoals Visual Studio .NET of in een andere toepassing van uw keuze. Autorisatieregels worden meestal geschreven door professionele ontwikkelaars.
Zie
Het gebruik van zakelijke regels en autorisatieregels beheren
Het gebruik beheren op elke client
Met ingang van Windows Server 2008 kan het gebruik van zakelijke regels en autorisatieregels worden beheerd met een registerinstelling. Regels zijn standaard uitgeschakeld. In eerdere versies van Windows werd deze functionaliteit niet ondersteund.
Doorgaans zult u gebruikmaken van een installatieprogramma of een script dat wordt uitgevoerd door het besturingssysteem om autorisatieregels en zakelijke regels in te schakelen als deze in uw omgeving worden gebruikt.
Belangrijk | |
Deze instelling wordt afzonderlijk beheerd voor elke Autorisatiebeheer-toepassing op elke client. |
Hier volgt een voorbeeldscript waarmee zakelijke regels en autorisatieregels voor een toepassing worden in- of uitgeschakeld:
'
' Enabling or disabling BizRules
for an application
' This script uses Authorization Manager Administrative interfaces to enable or disable
' BizRules for a specified Authorization Manager application in a specified Authorization Manager policy store
On Error Resume Next
Set objArgs = WScript.Arguments
If objArgs.count <> 3 then
wscript.echo "Usage: SetBizRule ""AzManStoreURL"" ""AzApplicaitonName"" True/False"
wscript.echo "Example: SetBizRule ""msxml://d:\inetpub\wwwroot\AzStore.xml"" ""MyApp"" True"
wscript.echo "Run with 'cscript' command in cmd.exe to avoid msg boxes"
Else
' VBScript source code
Dim AzStoreObj
Dim AzManStoreURL : AzManStoreURL = objArgs(0)
Dim AzManAppName : AzManAppName = objArgs(1)
Dim BizRulesEnabled : BizRulesEnabled = objArgs(2)
' create azman object
Set AzStoreObj = CreateObject("AzRoles.AzAuthorizationStore")
If Err.Number > 0 Then
WScript.Echo "Can not create AzRoles.AzAuthorizationStore. Check Authorization Manager installation"
WScript.Quit
End If
' initialize store for Administration
' assumes store exists - if store is being created (e.g. an installing applicaion)
' use the value 3 instead of 2 in the call to IAzAuthorizationStore::initialize
Err.Clear
AzStoreObj.Initialize 2, AzManStoreURL
If Err.Number <> 0 Then
WScript.Echo "AzRoles.AzAuthorizationStore failed to initialize. Check store URL"
WScript.Quit
End If
' open applicaion
set AzApp = AzStoreObj.OpenApplication(AzManAppName)
If Err.Number <> 0 Then
WScript.Echo "AzRoles.AzAuthorizationStore failed to open application: " + AzManAppName + ". Check application Name."
WScript.Quit
End If
' set BizRulesEnabled property
WSCript.Echo "App BizRule Before:" & AzApp.BizRulesEnabled
AzApp.BizRulesEnabled = BizRulesEnabled
WSCript.Echo "App BizRule After:" & AzApp.BizRulesEnabled
If Err.Number = 0 Then
WScript.Echo "BizRulesEnabled is updated successfully."
Else
WScript.Echo "BizRulesEnabled is NOT updated successfully."
End If
End if
Het gebruik beheren voor het gehele autorisatiearchief
Door de limieten voor de autorisatieregel te configureren op het tabblad Limieten van het eigenschappenvenster voor het autorisatiearchief, kunt u:
-
Autorisatieregels en zakelijke regels uitschakelen voor het archief.
-
Een time-outwaarde instellen om de maximale tijdsduur voor het uitvoeren van een script te beperken.
-
Scripts laten uitvoeren zonder time-out.
Zie Wat zijn limieten van Autorisatiebeheer-archieven? voor meer informatie.
Voorbeeld van VBScript
Dit is een autorisatieregel in VBScript waarmee altijd een machtiging wordt verleend:
AzBizRuleContext.BusinessRuleResult = True
Zie
Voorbeeld van JScript
Dit is een autorisatieregel in JScript waarmee altijd een machtiging wordt verleend:
AzBizRuleContext.BusinessRuleResult = true;
Zie