Reguły autoryzacji to skrypty napisane w języku VBScript lub JScript, w których można umieścić definicje ról i zadań. Reguła autoryzacji określa, czy rola lub zadanie jest dozwolone.

Używając reguł autoryzacji, można oprzeć decyzje dotyczące autoryzacji na dowolnych warunkach, które następnie można sprawdzić w skrypcie. Są to między innymi przywileje i uprawnienia, godzina, limity wydatków, stany kont i inne kryteria.

Menedżer autoryzacji nie jest przeznaczony do pisania lub debugowania reguł autoryzacji. Skrypty można pisać w edytorze tekstów (na przykład w Notatniku), w zintegrowanym środowisku dla deweloperów, takim jak Visual Studio .NET lub w innej aplikacji. Reguły autoryzacji są zwykle pisane przez deweloperów.

Więcej informacji o tworzeniu reguł autoryzacji i używaniu interfejsów programowania aplikacji (API) Menedżera autoryzacji znajduje się na stronie Model menedżera autoryzacji (strona może zostać wyświetlona w języku angielskim) (https://go.microsoft.com/fwlink/?linkid=64027). Aby uzyskać dodatkowe sugerowane łącza, zobacz temat Zasoby dla Menedżera autoryzacji.

Sterowanie używaniem reguł biznesowych i reguł autoryzacji

Sterowanie używaniem na każdym kliencie

Począwszy od systemu Windows Server 2008 wykorzystaniem reguł biznesowych i reguł autoryzacji może sterować ustawienie rejestru. Reguły są domyślnie wyłączone. Starsze wersje systemu Windows nie obsługują tej funkcjonalności.

Jeśli w danych środowisku używane są reguły autoryzacji i reguły biznesowe, wówczas do ich włączenia jest używany program instalacyjny lub skrypt uruchamiany przez system operacyjny.

Ważne

To ustawienie jest sterowane indywidualnie dla każdej aplikacji Menedżera autoryzacji na każdym komputerze klienckim.

Poniżej podany jest prosty skrypt włączający lub wyłączający reguły biznesowe i reguły aplikacji dla aplikacji.

'

' Enabling or disabling BizRules for an application

' This script uses Authorization Manager Administrative interfaces to enable or disable

' BizRules for a specified Authorization Manager application in a specified Authorization Manager policy store

On Error Resume Next

Set objArgs = WScript.Arguments

If objArgs.count <> 3 then

wscript.echo "Usage: SetBizRule ""AzManStoreURL"" ""AzApplicaitonName"" True/False"

wscript.echo "Example: SetBizRule ""msxml://d:\inetpub\wwwroot\AzStore.xml"" ""MyApp"" True"

wscript.echo "Run with 'cscript' command in cmd.exe to avoid msg boxes"

Else

' VBScript source code

Dim AzStoreObj

Dim AzManStoreURL : AzManStoreURL = objArgs(0)

Dim AzManAppName : AzManAppName = objArgs(1)

Dim BizRulesEnabled : BizRulesEnabled = objArgs(2)

' create azman object

Set AzStoreObj = CreateObject("AzRoles.AzAuthorizationStore")

If Err.Number > 0 Then

WScript.Echo "Can not create AzRoles.AzAuthorizationStore. Check Authorization Manager installation"

WScript.Quit

End If

' initialize store for Administration

' assumes store exists - if store is being created (e.g. an installing applicaion)

' use the value 3 instead of 2 in the call to IAzAuthorizationStore::initialize

Err.Clear

AzStoreObj.Initialize 2, AzManStoreURL

If Err.Number <> 0 Then

WScript.Echo "AzRoles.AzAuthorizationStore failed to initialize. Check store URL"

WScript.Quit

End If

' open applicaion

set AzApp = AzStoreObj.OpenApplication(AzManAppName)

If Err.Number <> 0 Then

WScript.Echo "AzRoles.AzAuthorizationStore failed to open application: " + AzManAppName + ". Check application Name."

WScript.Quit

End If

' set BizRulesEnabled property

WSCript.Echo "App BizRule Before:" & AzApp.BizRulesEnabled

AzApp.BizRulesEnabled = BizRulesEnabled

WSCript.Echo "App BizRule After:" & AzApp.BizRulesEnabled

If Err.Number = 0 Then

WScript.Echo "BizRulesEnabled is updated successfully."

Else

WScript.Echo "BizRulesEnabled is NOT updated successfully."

End If

End if

Sterowanie używaniem dla całego magazynu autoryzacji

Konfigurując ograniczenia reguły autoryzacji na karcie Ograniczenia arkusza właściwości magazynu autoryzacji, można:

  • wyłączać reguły autoryzacji i reguły biznesowe dla magazynu,

  • ustawiać wartość limitu czasu w celu ograniczenia maksymalnego czasu działania skryptu,

  • zezwalać na działanie skryptu bez limitu czasu.

Aby uzyskać więcej informacji, zobacz temat Opis ograniczeń magazynów Menedżera autoryzacji.

Przykład w języku VBScript

Poniższa reguła autoryzacji w języku VBScript zawsze udziela uprawnienia:

AzBizRuleContext.BusinessRuleResult = True

Aby uzyskać więcej informacji o języku VBScript, zobacz VBScript (strona może zostać wyświetlona w języku angielskim) (https://go.microsoft.com/fwlink/?linkid=65964).   

Przykład w języku JScript

Poniższa reguła autoryzacji w języku JScript zawsze udziela uprawnienia:

AzBizRuleContext.BusinessRuleResult = true;

Aby uzyskać więcej informacji o języku JScript, zobacz JScript (strona może zostać wyświetlona w języku angielskim) (https://go.microsoft.com/fwlink/?linkid=65963).   


Spis treści