Yetkilendirme kuralları VBScript veya JScript olarak yazılmış olan ve rol tanımlarına ve görev tanımlarına ekleyebileceğiniz komut dosyalarıdır. Yetkilendirme kuralı, rol veya göreve izin verilip verilmeyeceğini belirler.

Yetkilendirme kurallarını kullanarak, yetkilendirme kararlarını bir komut dosyasının sınayabileceği herhangi bir koşula dayandırabilirsiniz. Bunlar ayrıcalıkları ve izinleri, günün saati, faturalanabilecek masraf sınırları, hesap bakiyeleri ve diğer ölçütleri içerebilir.

Yetkilendirme Yöneticisi, yetkilendirme kurallarını yazmak veya yetkilendirme kurallarının hatalarını ayıklamak için tasarlanmamıştır. Komut satırlarınızı bir metin düzenleyicisinde (örneğin, Not Defteri), Visual Studio .NET gibi tümleşik bir geliştirme ortamında veya istediğiniz başka bir uygulamada yazabilirsiniz. Yetkilendirme kuralları genellikle profesyonel geliştiriciler tarafından yazılır.

Yetkilendirme kuralları oluşturma ve Yetkilendirme Yönetimi uygulama programlama arabirimlerini (API) kullanma hakkında daha fazla bilgi için, bkz. Yetkilendirme Yöneticisi Modeli (bu sayfa İngilizce içeriğe sahip olabilir) (https://go.microsoft.com/fwlink/?linkid=64027). Önerilen diğer bağlantılar için bkz. Yetkilendirme Yöneticisi Kaynakları.

İş kurallarının ve yetkilendirme kurallarının kullanımını denetleme

Her istemcideki kullanımı denetleme

Windows Server 2008'den itibaren, iş kurallarının ve yetkilendirme kurallarının kullanılması bir kayıt defteri ayarıyla denetlenebilmektedir. Kurallar varsayılan olarak devre dışıdır. Windows'un önceki sürümleri bu işlevselliği desteklemez.

Genellikle, ortamınızda kullanılıyorlarsa, iş kurallarını ve yetkilendirme kurallarını etkinleştirmek için işletim sisteminin çalıştırdığı bir kurulum programını veya komut dosyasını kullanırsınız.

Önemli

Bu ayar tüm istemcilerden her Yetkilendirme Yöneticisi için bağımsız olarak denetlenir.

Aşağıda, uygulamayla ilgili iş kurallarını ve uygulama kurallarını etkinleştiren veya devre dışı bırakan örnek komut dosyası vardır:

' Enabling or disabling BizRules for an application

' This script uses Authorization Manager Administrative interfaces to enable or disable

' BizRules for a specified Authorization Manager application in a specified Authorization Manager policy store

On Error Resume Next

Set objArgs = WScript.Arguments

If objArgs.count <> 3 then

wscript.echo "Usage: SetBizRule ""AzManStoreURL"" ""AzApplicaitonName"" True/False"

wscript.echo "Example: SetBizRule ""msxml://d:\inetpub\wwwroot\AzStore.xml"" ""MyApp"" True"

wscript.echo "Run with 'cscript' command in cmd.exe to avoid msg boxes"

Else

' VBScript source code

Dim AzStoreObj

Dim AzManStoreURL : AzManStoreURL = objArgs(0)

Dim AzManAppName : AzManAppName = objArgs(1)

Dim BizRulesEnabled : BizRulesEnabled = objArgs(2)

' create azman object

Set AzStoreObj = CreateObject("AzRoles.AzAuthorizationStore")

If Err.Number > 0 Then

WScript.Echo "Can not create AzRoles.AzAuthorizationStore. Check Authorization Manager installation"

WScript.Quit

End If

' initialize store for Administration

' assumes store exists - if store is being created (e.g. an installing applicaion)

' use the value 3 instead of 2 in the call to IAzAuthorizationStore::initialize

Err.Clear

AzStoreObj.Initialize 2, AzManStoreURL

If Err.Number <> 0 Then

WScript.Echo "AzRoles.AzAuthorizationStore failed to initialize. Check store URL"

WScript.Quit

End If

' open applicaion

set AzApp = AzStoreObj.OpenApplication(AzManAppName)

If Err.Number <> 0 Then

WScript.Echo "AzRoles.AzAuthorizationStore failed to open application: " + AzManAppName + ". Check application Name."

WScript.Quit

End If

' set BizRulesEnabled property

WSCript.Echo "App BizRule Before:" & AzApp.BizRulesEnabled

AzApp.BizRulesEnabled = BizRulesEnabled

WSCript.Echo "App BizRule After:" & AzApp.BizRulesEnabled

If Err.Number = 0 Then

WScript.Echo "BizRulesEnabled is updated successfully."

Else

WScript.Echo "BizRulesEnabled is NOT updated successfully."

End If

End if

Tüm yetkilendirme deposu için kullanımı denetleme

Yetkilendirme deposunun özellikler sayfasında Sınırlar sekmesindeki yetkilendirme kuralı sınırlarını yapılandırarak aşağıdakileri yapabilirsiniz:

  • Depoyla ilgili yetkilendirme kurallarını ve iş kurallarını devre dışı bırakma.

  • Komut dosyasının çalıştırılmasına izin verilecek en fazla süreyi sınırlamak için zaman aşımı değeri ayarlama.

  • Zaman aşımı değeri olmadan komut dosyalarının çalıştırılmasına izin verme.

Daha fazla bilgi için bkz: Yetkilendirme Yöneticisi Depo Sınırlarını Anlama.

VBScript örneği

Aşağıda, her zaman izin veren bir VBScript yetkilendirme kuralı gösterilmiştir:   

AzBizRuleContext.BusinessRuleResult = True

VBScript hakkında daha fazla bilgi için, bkz. VBScript (bu sayfa İngilizce içeriğe sahip olabilir) (https://go.microsoft.com/fwlink/?LinkId=65964).

JScript örneği

Aşağıda, her zaman izin veren bir JScript yetkilendirme kuralı gösterilmiştir:   

AzBizRuleContext.BusinessRuleResult = true;

JScript hakkında daha fazla bilgi için, bkz. JScript (bu sayfa İngilizce içeriğe sahip olabilir) (https://go.microsoft.com/fwlink/?LinkId=65963).


İçindekiler