استيعاب قواعد التخويل وقواعد العمل

مع البدء بالإصدار Windows Server 2008، يمكن التحكم في استخدام قواعد الأعمال وقواعد التخويل بواسطة إعداد تسجيل. يتم تعطيل القواعد بشكل افتراضي. ولا تدعم الإصدارات السابقة من Windows هذه الوظائف.

وبوجه عام، ستستخدم برنامج إعداد أو برنامج نصي يتم تشغيله بواسطة نظام التشغيل لتمكين قواعد التخويل وقواعد الأعمال في حالة استخدامها في البيئة الخاصة بك.

	هام
	يتم التحكم في هذا الإعداد لكل تطبيق "إدارة تخويل" على كل عميل بشكل منفرد.

يعد البرنامج التالي هو برنامج نصي عينة لتمكين قواعد الأعمال وقواعد التطبيقات أو تعطيلها لأحد التطبيقات:

'

' Enabling or disabling BizRules for an application

' This script uses Authorization Manager Administrative interfaces to enable or disable

' BizRules for a specified Authorization Manager application in a specified Authorization Manager policy store

On Error Resume Next

Set objArgs = WScript.Arguments

If objArgs.count <> 3 then

wscript.echo "Usage: SetBizRule ""AzManStoreURL"" ""AzApplicaitonName"" True/False"

wscript.echo "Example: SetBizRule ""msxml://d:\inetpub\wwwroot\AzStore.xml"" ""MyApp"" True"

wscript.echo "Run with 'cscript' command in cmd.exe to avoid msg boxes"

Else

' VBScript source code

Dim AzStoreObj

Dim AzManStoreURL : AzManStoreURL = objArgs(0)

Dim AzManAppName : AzManAppName = objArgs(1)

Dim BizRulesEnabled : BizRulesEnabled = objArgs(2)

' create azman object

Set AzStoreObj = CreateObject("AzRoles.AzAuthorizationStore")

If Err.Number > 0 Then

WScript.Echo "Can not create AzRoles.AzAuthorizationStore. Check Authorization Manager installation"

WScript.Quit

End If

' initialize store for Administration

' assumes store exists - if store is being created (e.g. an installing applicaion)

' use the value 3 instead of 2 in the call to IAzAuthorizationStore::initialize

Err.Clear

AzStoreObj.Initialize 2, AzManStoreURL

If Err.Number <> 0 Then

WScript.Echo "AzRoles.AzAuthorizationStore failed to initialize. Check store URL"

WScript.Quit

End If

' open applicaion

set AzApp = AzStoreObj.OpenApplication(AzManAppName)

If Err.Number <> 0 Then

WScript.Echo "AzRoles.AzAuthorizationStore failed to open application: " + AzManAppName + ". Check application Name."

WScript.Quit

End If

' set BizRulesEnabled property

WSCript.Echo "App BizRule Before:" & AzApp.BizRulesEnabled

AzApp.BizRulesEnabled = BizRulesEnabled

WSCript.Echo "App BizRule After:" & AzApp.BizRulesEnabled

If Err.Number = 0 Then

WScript.Echo "BizRulesEnabled is updated successfully."

Else

WScript.Echo "BizRulesEnabled is NOT updated successfully."

End If

End if

يمكنك عن طريق تكوين حدود قواعد التخويل على علامة التبويب الحدود لورقة خصائص مخزن التخويل:

• تعطيل قواعد التخويل وقواعد الأعمال للمخزن.
  
  
• تعيين قيمة مهلة لتقييد الحد الأقصى لطول الوقت للسماح بتشغيل برنامج نصي.
  
  
• السماح بتشغيل برامج نصية بدون مهلة.
  
  

لمزيد من المعلومات، راجع استيعاب حدود مخزن إدارة التخويل.