Présentation des règles d’autorisation et des règles métier

À partir de Windows Server 2008, l’utilisation des règles métier et des règles d’autorisation peut être contrôlée par un paramètre du Registre. Les règles sont désactivées par défaut. Les versions antérieures de Windows ne prenaient pas en charge cette fonctionnalité.

En règle générale, vous utilisez un programme d’installation ou un script exécuté par le système d’exploitation pour activer les règles d’autorisation et les règles métier si elles interviennent dans votre environnement.

	Important
	Ce paramètre est contrôlé séparément pour chaque application du Gestionnaire d’autorisations sur chaque client.

L’exemple de script suivant illustre l’activation ou la désactivation de règles métier et de règles d’autorisation pour une application :

'

' Enabling or disabling BizRules for an application

' This script uses Authorization Manager Administrative interfaces to enable or disable

' BizRules for a specified Authorization Manager application in a specified Authorization Manager policy store

On Error Resume Next

Set objArgs = WScript.Arguments

If objArgs.count <> 3 then

wscript.echo "Usage: SetBizRule ""AzManStoreURL"" ""AzApplicaitonName"" True/False"

wscript.echo "Example: SetBizRule ""msxml://d:\inetpub\wwwroot\AzStore.xml"" ""MyApp"" True"

wscript.echo "Run with 'cscript' command in cmd.exe to avoid msg boxes"

Else

' VBScript source code

Dim AzStoreObj

Dim AzManStoreURL : AzManStoreURL = objArgs(0)

Dim AzManAppName : AzManAppName = objArgs(1)

Dim BizRulesEnabled : BizRulesEnabled = objArgs(2)

' create azman object

Set AzStoreObj = CreateObject("AzRoles.AzAuthorizationStore")

If Err.Number > 0 Then

WScript.Echo "Can not create AzRoles.AzAuthorizationStore. Check Authorization Manager installation"

WScript.Quit

End If

' initialize store for Administration

' assumes store exists - if store is being created (e.g. an installing applicaion)

' use the value 3 instead of 2 in the call to IAzAuthorizationStore::initialize

Err.Clear

AzStoreObj.Initialize 2, AzManStoreURL

If Err.Number <> 0 Then

WScript.Echo "AzRoles.AzAuthorizationStore failed to initialize. Check store URL"

WScript.Quit

End If

' open applicaion

set AzApp = AzStoreObj.OpenApplication(AzManAppName)

If Err.Number <> 0 Then

WScript.Echo "AzRoles.AzAuthorizationStore failed to open application: " + AzManAppName + ". Check application Name."

WScript.Quit

End If

' set BizRulesEnabled property

WSCript.Echo "App BizRule Before:" & AzApp.BizRulesEnabled

AzApp.BizRulesEnabled = BizRulesEnabled

WSCript.Echo "App BizRule After:" & AzApp.BizRulesEnabled

If Err.Number = 0 Then

WScript.Echo "BizRulesEnabled is updated successfully."

Else

WScript.Echo "BizRulesEnabled is NOT updated successfully."

End If

End if

En configurant les limites de règle d’autorisation sous l’onglet Limites de la feuille de propriétés du magasin d’autorisations, vous pouvez :

• désactiver les règles d’autorisation et les règles métier du magasin ;
  
  
• définir une valeur de temporisation pour limiter la durée maximale impartie à l’exécution d’un script ;
  
  
• autoriser l’exécution des scripts sans temporisation.
  
  

Pour plus d’informations, voir Présentation des limites des magasins du Gestionnaire d’autorisations.