Grundlegendes zu Autorisierungs- und Geschäftsregeln

Beginnend mit Windows Server 2008 kann das Verwenden von Geschäftsregeln und Autorisierungsregeln mit einer Registrierungseinstellung gesteuert werden. Regeln sind standardmäßig deaktiviert. In früheren Versionen von Windows wurden diese Funktionen nicht unterstützt.

Im Allgemeinen wird ein Installationsprogramm oder ein vom Betriebssystem ausgeführtes Skript zum Aktivieren von Autorisierungsregeln und Geschäftsregeln verwendet, wenn diese an anderer Stelle in der Umgebung verwendet werden.

	Wichtig
	Diese Einstellung wird für jede Autorisierungs-Manager-Anwendung auf jedem einzelnen Client separat gesteuert.

Im Folgenden finden Sie ein Beispielskript, das Geschäfts- und Anwendungsregeln für eine Anwendung aktiviert oder deaktiviert:

'

' Enabling or disabling BizRules for an application

' This script uses Authorization Manager Administrative interfaces to enable or disable

' BizRules for a specified Authorization Manager application in a specified Authorization Manager policy store

On Error Resume Next

Set objArgs = WScript.Arguments

If objArgs.count <> 3 then

wscript.echo "Usage: SetBizRule ""AzManStoreURL"" ""AzApplicaitonName"" True/False"

wscript.echo "Example: SetBizRule ""msxml://d:\inetpub\wwwroot\AzStore.xml"" ""MyApp"" True"

wscript.echo "Run with 'cscript' command in cmd.exe to avoid msg boxes"

Else

' VBScript source code

Dim AzStoreObj

Dim AzManStoreURL : AzManStoreURL = objArgs(0)

Dim AzManAppName : AzManAppName = objArgs(1)

Dim BizRulesEnabled : BizRulesEnabled = objArgs(2)

' create azman object

Set AzStoreObj = CreateObject("AzRoles.AzAuthorizationStore")

If Err.Number > 0 Then

WScript.Echo "Can not create AzRoles.AzAuthorizationStore. Check Authorization Manager installation"

WScript.Quit

End If

' initialize store for Administration

' assumes store exists - if store is being created (e.g. an installing applicaion)

' use the value 3 instead of 2 in the call to IAzAuthorizationStore::initialize

Err.Clear

AzStoreObj.Initialize 2, AzManStoreURL

If Err.Number <> 0 Then

WScript.Echo "AzRoles.AzAuthorizationStore failed to initialize. Check store URL"

WScript.Quit

End If

' open applicaion

set AzApp = AzStoreObj.OpenApplication(AzManAppName)

If Err.Number <> 0 Then

WScript.Echo "AzRoles.AzAuthorizationStore failed to open application: " + AzManAppName + ". Check application Name."

WScript.Quit

End If

' set BizRulesEnabled property

WSCript.Echo "App BizRule Before:" & AzApp.BizRulesEnabled

AzApp.BizRulesEnabled = BizRulesEnabled

WSCript.Echo "App BizRule After:" & AzApp.BizRulesEnabled

If Err.Number = 0 Then

WScript.Echo "BizRulesEnabled is updated successfully."

Else

WScript.Echo "BizRulesEnabled is NOT updated successfully."

End If

End if

Durch Konfigurieren der Autorisierungsregellimits auf der Registerkarte Limits im Eigenschaftenblatt des Autorisierungsspeichers können Sie folgende Aufgaben ausführen:

• Deaktivieren von Autorisierungs- und Geschäftsregeln für den Speicher
  
  
• Festlegen eines Zeitlimitwerts zum Begrenzen der maximal zulässigen Zeit zum Ausführen eines Skripts
  
  
• Zulassen, dass Skripts ohne Timeout ausgeführt werden
  
  

Weitere Informationen finden Sie unter Grundlegendes zu Autorisierungs-Manager-Speicherlimits.